タイマーを使用してISRの変数を更新する方法

Timer3の周波数をカウンターで確認しようとしています。揮発性として宣言されたカウンターの値はISRでインクリメントされ、毎秒合計がメインループに表示され、値はゼロにリセットされます。

タイマーは正しく設定されています。（3Hzタイマーを選択すると、LEDが点滅します）

問題

カウンターはインクリメントされません。出力は次のとおりです。

Setup Completed
tick: 1
tick: 0
tick: 0
tick: 0

コード

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);

  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B = 20; // 800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM12);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();

  Serial.println("Setup completed");
}

void loop()
{
  if (millis() % 1000 == 0)
  {
    Serial.print(" tick: ");
    Serial.println(cont);
    cont = 0;
  }
}

ISR(TIMER3_COMPB_vect)
{
  //digitalWrite(13, digitalRead(13) ^ 1);
  cont++;
}

EDIT このタイマーは、加速度計からanlog値を読み取り、floatの配列に格納するために使用されます。しかし、現時点では、このアップデートの問題に行き詰まっています。

ソリューション1 Gerbenのおかげ

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3A = 20; // 20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  delay(1000);
  Serial.println(cont);
  cont = 0;
}

ISR(TIMER3_COMPB_vect)
{
  cont++;
}

ソリューション2 BrettMのおかげで

volatile int cont = 0;

void setup()
{
  Serial.begin(9600);
  pinMode(13, OUTPUT);

  // Initialize Timer
  cli();          // disable global interrupts
  TCCR3A = 0;     // set entire TCCR3A register to 0
  TCCR3B = 0;     // same for TCCR3B

  // set compare match register to desired timer count: 800 Hz
  OCR3B =  20; //800Hz 5; // 3 Hz
  // turn on CTC mode:
  //TCCR3B |= (1 << WGM32);
  // Set CS10 and CS12 bits for 1024 prescaler:
  TCCR3B |= (1 << CS30) | (1 << CS32);
  // enable timer compare interrupt:
  TIMSK3 |= (1 << OCIE3B);
  // enable global interrupts:
  sei();
  Serial.println("Setup completed");
}

void loop()
{
  Serial.println(cont); 
  cont = 0;
  delay(1000);

}

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

CTCモードでは、トップではOCR3AありませんOCR3B。

それは、後にTIMSK3 |= (1 << OCIE3B);もに変更しなければならないTIMSK3 |= (1 << OCIE3A);、とISR(TIMER3_COMPB_vect)しますISR(TIMER3_COMPA_vect)

3Hzの場合、OCR3A20ではなく5208 にする必要があります。

技術的にTCCR3B |= (1 << WGM12);はTCCR3B |= (1 << WGM32);

CTCモードはOCR3A Gerbenでのみ機能することを指摘してくれてありがとう、この質問に対する私の答えは以前は不完全だったようです。投稿する前にテストを行わなかったことをお詫びします。

この質問のみの情報を考慮して、Gerbenの回答は完全ですが、他の質問は、サーボライブラリが原因でOCR3Aを使用できないことを示唆しているため、少し追加します。（私もその答えを編集しました）

割り込みルーチンでTCNT3を0に設定することにより、CTCモードの動作をエミュレートできます。コードでCTCモードをオンにする行を忘れずに削除してください。

このISRでコードをテストしました。

ISR(TIMER3_COMPB_vect)
{
  TCNT3 = 0;
  cont++;
}

タイマーレジスタのこの構成

OCR3B = 5208; // 800Hz 5; // 3 Hz
// Set CS10 and CS12 bits for 1024 prescaler:
TCCR3B |= (1 << CS30) | (1 << CS32);
// enable timer compare interrupt:
TIMSK3 |= (1 << OCIE3B);

これは高周波数ではCTCよりも少し正確ではないかもしれませんが、わかりませんが、3Hzでは完全に機能しました。5208は20ではなく正しいOCR値であることに注意してください（これもGerbenのおかげです）。