PWM周波数を25 kHzに設定

現在、次のコードで4つのPWMピンを約31 kHzに設定できます。

void setup()
{
    TCCR1B = TCCR1B & B11111000 | B00000001; // Set PWM frequency for D9 & D10:
    pinMode(pwmPin9, OUTPUT); // Sets the pin as output
    pinMode(pwmPin10, OUTPUT); // Sets the pin as output


    TCCR2B = TCCR2B & B11111000 | B00000001; // Set PWM for D3 & D11
    pinMode(pwmPin3, OUTPUT); // Sets the pin as output
    pinMode(pwmPin11, OUTPUT); // Sets the pin as output
}

どこかでこの設定を見つけましたが、代わりにこれらの4つのPWMピンを約25 kHzに設定する方法がわかりません。そんなことがあるものか？

単一のArduino Unoで161ステップの25 kHzの4つのPWMチャネルを持つことが可能であることを理解したので、この2番目の回答を投稿します。これには、メインクロック周波数を8 MHzに変更することが含まれます。これは、プログラム全体が半分の速度で実行されるため、いくつかの副作用があります。また、3個のタイマ、Arduinoのタイミング機能を失う手段を再構成することを含む（millis()、micros()、delay()および delayMicroseconds()）。これらのトレードオフが許容できる場合は、次のようになります。

void setup()
{
    // Set the main system clock to 8 MHz.
    noInterrupts();
    CLKPR = _BV(CLKPCE);  // enable change of the clock prescaler
    CLKPR = _BV(CLKPS0);  // divide frequency by 2
    interrupts();

    // Configure Timer 0 for phase correct PWM @ 25 kHz.
    TCCR0A = 0;           // undo the configuration done by...
    TCCR0B = 0;           // ...the Arduino core library
    TCNT0  = 0;           // reset timer
    TCCR0A = _BV(COM0B1)  // non-inverted PWM on ch. B
        | _BV(WGM00);  // mode 5: ph. correct PWM, TOP = OCR0A
    TCCR0B = _BV(WGM02)   // ditto
        | _BV(CS00);   // prescaler = 1
    OCR0A  = 160;         // TOP = 160

    // Same for Timer 1.
    TCCR1A = 0;
    TCCR1B = 0;
    TCNT1  = 0;
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
        | _BV(COM1B1)  // same on ch. B
        | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
        | _BV(CS10);   // prescaler = 1
    ICR1   = 160;

    // Same for Timer 2.
    TCCR2A = 0;
    TCCR2B = 0;
    TCNT2  = 0;
    TCCR2A = _BV(COM2B1)  // non-inverted PWM on ch. B
        | _BV(WGM20);  // mode 5: ph. correct PWM, TOP = OCR2A
    TCCR2B = _BV(WGM22)   // ditto
        | _BV(CS20);   // prescaler = 1
    OCR2A  = 160;
}

void loop()
{
    analogWrite( 3,   1);  // duty cycle = 1/160
    analogWrite( 5,  53);  // ~ 1/3
    analogWrite( 9, 107);  // ~ 2/3
    analogWrite(10, 159);  // 159/160
}

他の回答とは異なり、これはの変更されたバージョンを必要としませんanalogWrite()。標準の回答は 正常に機能します。次のことに注意してください。

1. 書き込まれる値は、0（常にLOW）と160（常にHIGH）の間でなければなりません。
2. ピン3、5、9、および10のみが使用可能です。analogWrite() ピン6または11に接続しようとすると、PWM出力の配信に失敗するだけでなく、ピン5または3の周波数もそれぞれ変化します。

位相補正PWMモードで25 kHzでサイクルするようにタイマー1を構成し、ピン9と10で2つの出力を使用することができます。

// PWM output @ 25 kHz, only on pins 9 and 10.
// Output value should be between 0 and 320, inclusive.
void analogWrite25k(int pin, int value)
{
    switch (pin) {
        case 9:
            OCR1A = value;
            break;
        case 10:
            OCR1B = value;
            break;
        default:
            // no other pin will work
            break;
    }
}

void setup()
{
    // Configure Timer 1 for PWM @ 25 kHz.
    TCCR1A = 0;           // undo the configuration done by...
    TCCR1B = 0;           // ...the Arduino core library
    TCNT1  = 0;           // reset timer
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
           | _BV(COM1B1)  // same on ch; B
           | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
           | _BV(CS10);   // prescaler = 1
    ICR1   = 320;         // TOP = 320

    // Set the PWM pins as output.
    pinMode( 9, OUTPUT);
    pinMode(10, OUTPUT);
}

void loop()
{
    // Just an example:
    analogWrite25k( 9, 110);
    analogWrite25k(10, 210);
    for (;;) ;  // infinite loop
}

で値0を書き込むanalogWrite25k()と、ピンは常にLOWになりますが、320は常にHIGHを意味します。レギュラーanalogWrite() はほぼ機能するはずですが、255は320と同じように解釈されます（つまり、常にHIGH）。

このコードは、Arduino Unoまたは同様のボード（ATmega168または328 @ 16 MHz）を想定しています。ここで使用する方法には16ビットタイマーが必要です。そのため、Unoで使用できるのはタイマー1だけなので、タイマー1を使用します。そのため、2つの出力しか使用できません。この方法は、16ビットタイマーを備えた他のAVRベースのボードに適応できます。Gerbenが述べたように、そのタイマーには対応するICRxレジスタが必要です。Arduino Megaには4つのタイマーがあり、それぞれに3つの出力があります。