着信文字列を分割するにはどうすればよいですか？

次の形式で、シリアル接続を介してarduinoにサーボ位置のリストを送信しています

1:90&2:80&3:180

次のように解析されます：

servoId : Position & servoId : Position & servoId : Position

これらの値をどのように分割し、整数に変換するのですか？

他の答えとは反対に、私Stringは次の理由から遠ざかりたいです。

• 動的なメモリ使用量（すぐにヒープの断片化とメモリ枯渇につながる可能性があります）
• 建設/破壊/割り当てオペレータのために非常に遅い

Arduinoのような組み込み環境では（SRAMが多いMegaでも）、標準のC関数を使用します：

• strchr()：C文字列内の文字を検索します（つまりchar *）
• strtok()：区切り文字に基づいて、C文字列を部分文字列に分割します
• atoi()：C文字列をに変換します int

これは、次のコードサンプルにつながります。

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30
...

// Get next command from Serial (add 1 for final 0)
char input[INPUT_SIZE + 1];
byte size = Serial.readBytes(input, INPUT_SIZE);
// Add the final 0 to end the C string
input[size] = 0;

// Read each command pair 
char* command = strtok(input, "&");
while (command != 0)
{
    // Split the command in two values
    char* separator = strchr(command, ':');
    if (separator != 0)
    {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);

        // Do something with servoId and position
    }
    // Find the next command in input string
    command = strtok(0, "&");
}

ここでの利点は、動的なメモリ割り当てが行われないことです。inputコマンドを読み取って実行する関数内でローカル変数として宣言することもできます。関数が返されると、input（スタック内の）占有サイズが回復されます。

この関数を使用して、分離文字が何であるかに基づいて文字列を断片に分離できます。

String xval = getValue(myString, ':', 0);
String yval = getValue(myString, ':', 1);

Serial.println("Y:" + yval);
Serial.print("X:" + xval);

文字列をintに変換

int xvalue = stringToNumber(xval);
int yvalue = stringToNumber(yval);

このコードのチャンクは文字列を受け取り、指定された文字に基づいてそれを分離し、返します

String getValue(String data, char separator, int index)
{
    int found = 0;
    int strIndex[] = { 0, -1 };
    int maxIndex = data.length() - 1;

    for (int i = 0; i <= maxIndex && found <= index; i++) {
        if (data.charAt(i) == separator || i == maxIndex) {
            found++;
            strIndex[0] = strIndex[1] + 1;
            strIndex[1] = (i == maxIndex) ? i+1 : i;
        }
    }
    return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

次のようなことができますが、いくつかのことを考慮してください。

を使用する場合readStringUntil()、文字またはタイムアウトを受信するまで待機します。したがって、現在の文字列では、待機する必要があるため、最後の位置が少し長くなります。&このタイムアウトを回避するために、末尾を追加できます。モニターでこの動作を簡単に確認し、余分な文字列を使用して、または追加せずに文字列を送信しよう&とすると、そのようなタイムアウト遅延が表示されます。

実際にはサーボインデックスは必要ありません。位置の文字列を送信するだけで、文字列内の値の位置からサーボインデックスを取得できます90&80&180&。サーボインデックスを使用する場合は、それをチェックして（に変換しint、ループインデックスiに一致させて）、メッセージに問題がないことを確認する必要があります。

から返される文字列readStringUntilが空でないことを確認する必要があります。関数がタイムアウトした場合、十分なデータを受信できなかったため、int値を抽出しようとすると奇妙な結果が生じます。

void setup() {
    Serial.begin(9600);
}

void loop() {
    for(int i=1; i<=3; i++) {
        String servo = Serial.readStringUntil(':');
        if(servo != ""){
            //here you could check the servo number
            String pos = Serial.readStringUntil('&');
            int int_pos=pos.toInt();
            Serial.println("Pos");
            Serial.println(int_pos);
        }
    }
}

Stream.readStringUntil(terminator)パーツごとに異なるターミネーターを渡すことを使用できます。

その後、各部分で呼び出します String.toInt

最も簡単な解決策は、sscanf（）を使用することです。

  int id1, id2, id3;
  int pos1, pos2, pos3;
  char* buf = "1:90&2:80&3:180";
  int n = sscanf(buf, "%d:%d&%d:%d&%d:%d", &id1, &pos1, &id2, &pos2, &id3, &pos3);
  Serial.print(F("n="));
  Serial.println(n);
  Serial.print(F("id1="));
  Serial.print(id1);
  Serial.print(F(", pos1="));
  Serial.println(pos1);
  Serial.print(F("id2="));
  Serial.print(id2);
  Serial.print(F(", pos2="));
  Serial.println(pos2);
  Serial.print(F("id3="));
  Serial.print(id3);
  Serial.print(F(", pos3="));
  Serial.println(pos3);

これにより、次の出力が得られます。

n=6
id1=1, pos1=90
id2=2, pos2=80
id3=3, pos3=180

乾杯！

https://github.com/BenTommyE/Arduino_getStringPartByNrの例を参照してください

// splitting a string and return the part nr index split by separator
String getStringPartByNr(String data, char separator, int index) {
    int stringData = 0;        //variable to count data part nr 
    String dataPart = "";      //variable to hole the return text

    for(int i = 0; i<data.length()-1; i++) {    //Walk through the text one letter at a time
        if(data[i]==separator) {
            //Count the number of times separator character appears in the text
            stringData++;
        } else if(stringData==index) {
            //get the text when separator is the rignt one
            dataPart.concat(data[i]);
        } else if(stringData>index) {
            //return text and stop if the next separator appears - to save CPU-time
            return dataPart;
            break;
        }
    }
    //return text if this is the last part
    return dataPart;
}

String getValue(String data, char separator, int index)
{
    int maxIndex = data.length() - 1;
    int j = 0;
    String chunkVal = "";

    for (int i = 0; i <= maxIndex && j <= index; i++)
    {
        chunkVal.concat(data[i]);

        if (data[i] == separator)
        {
            j++;

            if (j > index)
            {
                chunkVal.trim();
                return chunkVal;
            }

            chunkVal = "";
        }
        else if ((i == maxIndex) && (j < index)) {
            chunkVal = "";
            return chunkVal;
        }
    }   
}

jfpoilpretは、Arduinoでシリアルコマンドを解析するための優れた答えを提供しました。ただし、Atiny85には双方向シリアルがありません。SoftwareSerialを使用する必要があります。これはAttiny85に同じコードを移植する方法です

#include <SoftwareSerial.h>

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30

// Initialize SoftwareSerial
SoftwareSerial mySerial(3, 4); // RX=PB3, TX=PB4

// Parameter for receiving Serial command (add 1 for final 0)
char input[INPUT_SIZE + 1];

void setup() {
  mySerial.begin(9600);
}

void loop() {
  // We need this counter to simulate Serial.readBytes which SoftwareSerial lacks
  int key = 0;

  // Start receiving command from Serial
  while (mySerial.available()) {
    delay(3);  // Delay to allow buffer to fill, code gets unstable on Attiny85 without this for some reason
    // Don't read more characters than defined
    if (key < INPUT_SIZE && mySerial.available()) {
      input[key] = mySerial.read();
      key += 1;
    }
  }

  if (key > 0) {
    // Add the final 0 to end the C string
    input[key] = 0;

    // Read each command pair
    char* command = strtok(input, "&");
    while (command != 0)
    {
      // Split the command in two values
      char* separator = strchr(command, ':');
      if (separator != 0)
      {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);
      }
      // Find the next command in input string
      command = strtok(0, "&");
    }
  }
}

ピン番号のAttiny85回路図

Sketchは以下にコンパイルされます：

Sketch uses 2244 bytes (27%) of program storage space. Maximum is 8192 bytes.
Global variables use 161 bytes (31%) of dynamic memory, leaving 351 bytes for local variables. Maximum is 512 bytes.

したがって、残りのコード用に十分なスペースとメモリがあります

char str[] = "1:90&2:80&3:180";     // test sample serial input from servo
int servoId;
int position;

char* p = str;
while (sscanf(p, "%d:%d", &servoId, &position) == 2)
{
    // process servoId, position here
    //
    while (*p && *p++ != '&');   // to next id/pos pair
}

void setup() {
Serial.begin(9600);
char str[] ="1:90&2:80";
char * pch;
pch = strtok(str,"&");
printf ("%s\n",pch);

pch = strtok(NULL,"&"); //pch=next value
printf ("%s\n",pch);
}
void loop(){}

以下は、「部分文字列で文字列を分割する方法」という質問に対する答えとして、文字列を分割するArduinoメソッドです。現在の質問の複製として宣言されています。

ソリューションの目的は、SDカードファイルに記録された一連のGPS位置を解析することです。から文字列を受け取る代わりに、文字列はファイルから読み取られます。Serial

この関数はあるStringSplit()文字列パースsLine = "1.12345,4.56789,hello"3つの文字列にsParams[0]="1.12345"、sParams[1]="4.56789"＆sParams[2]="hello"。

1. String sInput：解析される入力行、
2. char cDelim：パラメーター間の区切り文字、
3. String sParams[]：パラメータの出力配列、
4. int iMaxParams：パラメーターの最大数、
5. 出力int：解析されたパラメーターの数、

この関数はString::indexOf()およびに基づいていString::substring()ます：

int StringSplit(String sInput, char cDelim, String sParams[], int iMaxParams)
{
    int iParamCount = 0;
    int iPosDelim, iPosStart = 0;

    do {
        // Searching the delimiter using indexOf()
        iPosDelim = sInput.indexOf(cDelim,iPosStart);
        if (iPosDelim > (iPosStart+1)) {
            // Adding a new parameter using substring() 
            sParams[iParamCount] = sInput.substring(iPosStart,iPosDelim-1);
            iParamCount++;
            // Checking the number of parameters
            if (iParamCount >= iMaxParams) {
                return (iParamCount);
            }
            iPosStart = iPosDelim + 1;
        }
    } while (iPosDelim >= 0);
    if (iParamCount < iMaxParams) {
        // Adding the last parameter as the end of the line
        sParams[iParamCount] = sInput.substring(iPosStart);
        iParamCount++;
    }

    return (iParamCount);
}

そして、使い方は本当に簡単です：

String sParams[3];
int iCount, i;
String sLine;

// reading the line from file
sLine = readLine();
// parse only if exists
if (sLine.length() > 0) {
    // parse the line
    iCount = StringSplit(sLine,',',sParams,3);
    // print the extracted paramters
    for(i=0;i<iCount;i++) {
        Serial.print(sParams[i]);
    }
    Serial.println("");
}