DMGファイルを開くときに、ウィンドウの前で開くにはどうすればよいですか？

.dmgファイルをダウンロードしてから（通常はChromeのダウンロードバーから）開くと、バックグラウンドで開きます。ウィンドウの前で開く方法はありますか？

編集

明確にするために、アクティブなウィンドウとしてDMGウィンドウがポップアップするようにします。

ApplescriptでFolder Actionスクリプトを作成しましたが、それはあなたが望むことをするかもしれません。それをコピーして新しいApplescriptに貼り付け、アプリケーションとして（開始ダイアログなしで！）「/ライブラリ/ Scripts / Folder Action Scripts /」に保存します。フォルダーを右クリックし、サービスのドロップアウトメニューから[フォルダーアクションの構成]を選択することで、任意のフォルダー（ほとんどの場合〜/ Downloads / folder）に添付できます。フォルダアクションをアクティブにし、スクリプトがフォルダを監視できるようにします。

スクリプトが基本的に行うことは、アタッチされたフォルダーにドロップされたアイテムに反応し、ドロップされたアイテムがKind： "Image"の場合、 "hdiutil"コマンドラインツールを介してボリュームとしてイメージをアタッチします。

スクリプトでopenWindowプロパティとmakeFrontmostプロパティを設定することにより、その動作を構成できます。これは、スクリプトをアプリケーションとして保存した後、スクリプトをダブルクリックすることでも実行できます。標準の動作を2つのダイアログで確認します。

これがお役に立てば幸いです、

アスマス

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

フォルダーにドロップされたファイルの種類を決定する2番目のApplescript

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

編集は、「イメージ」ではなく「ディスクイメージ」である必要があります

私の知る限り、OS Xは読み取り専用のディスクイメージの内容のみを自動的に表示します。これは、画像の内容を表示するときに、Finderウィンドウの左下にスラッシュが付いた鉛筆で示されます。

これを行うようにディスクイメージを変更する場合は、ディスクユーティリティを使用して、既存のディスクイメージを読み取り専用にすることができます。残念ながら、これにより、インターネットからダウンロードする可能性のある誤って作成された画像の動作は変わりません。

1. 自動的に開くディスクイメージをマウントします。
2. Spotlightで検索してディスクユーティリティを開きます。
3. ツールバーの「新しい画像」アイコンを選択します。
4. ファイルに名前を付け、[画像形式]で[読み取り専用]を選択します。
5. [保存]をクリックします。この新しいイメージをマウントすると、Finderウィンドウが自動的に開きます。

これでもおそらく十分に質問に答えられませんが、...

コマンドを押してダウンロードバーのアイテムをクリックすると、ファインダーにアイテムが表示されます。その時点で、command-Oを押す（またはdmgファイルをダブルクリックする）だけで、それをマウントし、フォアグラウンドの新しいウィンドウで開きます。