Mac OSX Dictionary.appをGoogle翻訳にバインドできますか？

辞書アプリはMacOSXで非常に素晴らしい体験をします。しかし、使用するには辞書をインストールする必要があります。Google翻訳にバインドすることは可能ですか？

ありがとう！

残念ながら、それは不可能であるか、少なくとも簡単なようです。代わりに、選択した強調表示された単語またはフレーズに対して、ブラウザウィンドウでGoogle翻訳を開くOS X サービスの作成を検討することもできます。

これが適切に聞こえる場合は、以下の手順に従ってください。

翻訳サービスの作成

• フォルダAutomatorからアプリを開くApplications
• Serviceドキュメントのタイプとして選択し、クリックしますChoose
• 表示されるウィンドウで、検索フィールドをクリックして「AppleScript」と入力します
• Run AppleScript左側のリストから「アクションまたはファイルをここにドラッグしてワークフローを構築します」というラベルの付いた領域にアクションをドラッグアンドドロップします

以下のスクリプトをコピーして、Run Applescriptアクションに貼り付けます。

on run {input, parameters}
    set phrase to input as string
    set phrase to quoted form of phrase

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "zh-CN"

    do shell script "open 'https://translate.google.com/?hl='" & ui_lang & "'&sl='" & from_lang & "'&tl='" & to_lang & "'&text='" & phrase
end run

ウィンドウは次のようになります。

上記のスクリプトで変更したい値が3つあります。

• ui_lang -ページのインターフェースに使用される言語
• from_lang -ソース言語
• to_lang -宛先言語

これらの1つ以上を変更して、目的の翻訳を実現します。正しい言語パラメーターを見つけるには、「言語リファレンス」を参照してください。上記の例でenはEnglish、とzh-CN、中国語（簡体字）を指します。

変更後、File> Save...をクリックし、表示されるパネルで適切な名前（例：）を入力しTranslate English to Chineseます。

翻訳サービスの使用

上記のワークフローを保存した後、次の2つの方法のいずれかで翻訳サービスを利用できます。

1.サービスメニューメソッド

• 任意のアプリケーションで単語または語句を強調表示する
• Appleアイコン（of）の右側にあるアプリケーションメニューをクリックし、[ ServicesおよびTranslate English to Chinese（またはサービスを保存するときにサービスに付けた名前）をクリックします。

2.コンテキストメニューメソッド

• 任意のアプリケーションで単語または語句を強調表示する
• テキストを右クリックし、Services次にTranslate English to Chinese（またはカスタムの名前付きサービス）を選択します。

どちらの方法を使用しても、翻訳されたテキストがブラウザウィンドウに表示されます。

これはsoulcakeの答えのようなすべてを行いますが、翻訳者のURLがすでに存在する場合-同じタブに新しい翻訳を読み込みます

on run {input, parameters}
    set phrase to input as string

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "ru"

    set theBaseUrl to "https://translate.google.com/"
    set theUrl to theBaseUrl & "?hl=" & ui_lang & "&sl=" & from_lang & "&tl=" & to_lang & "&text=" & phrase

    tell application "Google Chrome"
        activate

        if (count every window) = 0 then
            make new window
        end if

        set found to false
        set theTabIndex to -1
        repeat with theWindow in every window
            set theTabIndex to 0
            repeat with theTab in every tab of theWindow
                set theTabIndex to theTabIndex + 1
                if theTab's URL starts with theBaseUrl then
                    set found to true
                    exit repeat
                end if
            end repeat

            if found then
                exit repeat
            end if
        end repeat

        if found then
            set URL of theTab to theUrl
            set theWindow's active tab index to theTabIndex
            set index of theWindow to 1
        else
            tell window 1 to make new tab with properties {URL:theUrl}
        end if
    end tell

end run