ヨセミテに切り替えてからAppleScriptの「遅延」コマンドが機能しない

注：の問題delayはOS X 10.11 El Capitanで修正されました。

ヨセミテにアップグレードしてから、遅延を使用するApplescriptが機能しなくなりました。どうすれば修正できますか？

簡単な例として、世界で最も単純なApplescriptを以下に示します。

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

完了するまで30秒かかります。スクリプトエディター（以前のApplescriptエディター）で実行すると、完了までに30秒かかります。しかし、このスクリプトをアプリとして保存した場合、アプリを起動すると、遅延は無視され、アプリの完了までに数分の1秒かかります。

Applescriptに次のステップに進む前に指定した時間だけ遅延させるにはどうすればよいですか？これはヨセミテの不具合ですか？信頼できる回避策はありますか？

注：の問題delayはOS X 10.11 El Capitanで修正されました。

@ 2oh1、あなたはあなたの答えに正しい基本的な考えを持っていますが、ここに完全で正しい答えがあります：

これを回避するための唯一の妥当な方法は、ループの中で「遅延」を呼び出して、続行する前に必要な期間が経過することを保証することです。これを行う最善の方法は、カスタムハンドラーで「遅延」をオーバーライドすることです。

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

これにより、残りのスクリプトを変更せずにそのままにして、通常は「遅延」を使用できます。たとえば、

delay 5
display alert "I like cake!"

[注：通常、カスタムハンドラーは "continue delay duration"を使用して組み込みの "delay"を呼び出しますが、これはスクリプトエディター内で機能しますが、アプレット内で使用するとエラーを返すことがわかりました（ "Can ' t継続遅延（-1708）」）。私は、「続行」を使用する代わりに遅延コマンドを処理するようAppleScriptに直接指示することで、この問題を回避しました。]

問題はdelay、スクリプトの一時停止中にユーザー入力を処理するため、アプレットによって表示されたメニューまたはウィンドウをクリックすることができ、ユーザー入力がdelayスクリプトの実行を再開する前に完全な期間待機しないというバグがあります（10.11で修正）。。アプレットと対話しない場合、delay正しく動作します。

この同じ問題と戦いながら、あまり関係のない質問にこの答えを見つけ、それを試すことにしましたが、私にはうまくいくようです。

単純に置き換えるdelay 5とdo shell script "/bin/sleep 5"、同じ結果を得ます。

これが最善の解決策であるとは言いませんが、私の問題は解決したようです。理解できない理由で無視されている単純な遅延を使用する代わりに、時間を取得して新しい時間に到達するまでループするように切り替えました（それでも遅延が使用されますが、無視しても問題ありません）スクリプトが時間に達するまで続行されないための遅延）。

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

なぜ遅延が無視されているのか（または劇的にスピードアップしているのか？！???）まだ知りたくありませんが、これで仕事が完了します。

ドイツのフォーラム投稿で回避策を見つけました。次の行をスクリプトの先頭に追加します。

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

carzyjは私が最良の答えだと思うものでしたが、Chris Pageの方法と組み合わせると、次のようになります。

on delay duration
  do shell script "/bin/sleep " & duration
end delay

「遅延」から「遅延終了」までコメントアウトして、元の遅延に戻すことができます。

これは@ chris-pageソリューションの変更です

それは、応答性と正確に遅延を捕捉することの間のバランスのようです。

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

ただし、全体の期間にわたって遅延するようにApplescriptに指示する代わりに、期間の端数期間だけ遅延するように指示します。期間がアップルの許容範囲（1/60秒）未満の場合は、そのデルタに設定します。ある程度の応答性を維持しながら、まだ正確であること。疑わしいのは、遅延が機能しない場合があるため、繰り返しwhileループがスレッドをロックしたままにすることですが、成功シナリオでは、プロセスを中断できるように遅延デルタを短くする必要があります。

だから、すべてをまとめると、クリスはこれを意味すると信じています：

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay